@echo off
setlocal

set VERSION_URL=https://git.ihateamerica.ru/caps_enhancer/version.json
set ZIP_URL=https://git.ihateamerica.ru/caps_enhancer/caps-enhancer.zip
set TMP_ZIP=%TEMP%\caps-enhancer-update.zip
set TMP_VER=%TEMP%\caps-ver.json
set TMP_LOC=%TEMP%\caps-loc.txt
set TMP_FIL=%TEMP%\caps-fil.txt

set EXT_DIR=%~dp0
if "%EXT_DIR:~-1%"=="\" set EXT_DIR=%EXT_DIR:~0,-1%

findstr "version" "%EXT_DIR%\manifest.json" > "%TMP_LOC%"
findstr /v "manifest" "%TMP_LOC%" > "%TMP_FIL%"
for /f "usebackq tokens=2 delims=:," %%v in ("%TMP_FIL%") do set LOCAL_VER=%%v
set LOCAL_VER=%LOCAL_VER: =%
set LOCAL_VER=%LOCAL_VER:"=%

curl -sf "%VERSION_URL%" -o "%TMP_VER%"
if errorlevel 1 (
    echo [ERROR] Server unavailable
    goto :end
)
for /f "usebackq tokens=2 delims=:}" %%v in ("%TMP_VER%") do set REMOTE_VER=%%v
set REMOTE_VER=%REMOTE_VER: =%
set REMOTE_VER=%REMOTE_VER:"=%

del "%TMP_LOC%" "%TMP_FIL%" "%TMP_VER%" 2>nul

echo Local: %LOCAL_VER%  Remote: %REMOTE_VER%

if "%LOCAL_VER%"=="%REMOTE_VER%" (
    echo [OK] Already up to date
    goto :end
)

echo [INFO] Updating %LOCAL_VER% -^> %REMOTE_VER%

curl -f "%ZIP_URL%" -o "%TMP_ZIP%"
if errorlevel 1 (
    echo [ERROR] Download failed
    goto :end
)

tar -xf "%TMP_ZIP%" -C "%EXT_DIR%"
del "%TMP_ZIP%"

echo [OK] Updated to %REMOTE_VER%. Reload extension in chrome://extensions

:end
endlocal
pause